The following code was suggested by K. Hamilton and tested by A. Tanasijczuk.

In the Born_phsp.f file (located in POWHEG-BOX/gg_H_quark-mass-effects/ directory), change the subroutine set_fac_ren_scales(muf,mur).

Original subrutine:

      subroutine set_fac_ren_scales(muf,mur)
C     The following routine sets the renormalization and factorization scales
C     IMPORTANT: if a kinematic-dependent scale is adopted, remember
C     that only the Born kinematics is considered, since this function is called 
C     inside the btilde function before che construction of the real phase space.
      implicit none
      include 'PhysPars.h'
      include 'nlegborn.h'
      include 'pwhg_flst.h'
      include 'pwhg_kn.h'
      real * 8 muf,mur
      logical ini
      data ini/.true./
      real *8 muref
      real *8 dotp
      external dotp
      logical runningscales
      save runningscales
      real * 8 powheginput
      external powheginput
      if(ini) then
         if(powheginput('#runningscale').ge.1) then
            runningscales=.true.
         else
            runningscales=.false.
         endif
      endif
      if (runningscales) then
         if (ini) then
            write(*,*) '*************************************'
            write(*,*) '    Factorization and renormalization '
            if (powheginput('#runningscale').eq.1) then
               write(*,*) '    scales set to the H virtuality '
            else
               write(*,*) "runningscale value not allowed"
               call exit(1)
            endif
            write(*,*) '*************************************'
            ini=.false.
         endif
         muref=sqrt(dotp(kn_pborn(0,3),kn_pborn(0,3)))
      else
         if (ini) then
            write(*,*) '*************************************'
            write(*,*) '    Factorization and renormalization '
            write(*,*) '    scales set to the H mass '
            write(*,*) '*************************************'
            ini=.false.
         endif
         muref=ph_Hmass
      endif
      muf=muref
      mur=muref
      end

Modified subrutine:

      subroutine set_fac_ren_scales(muf,mur)
C     The following routine sets the renormalization and factorization scales
C     IMPORTANT: if a kinematic-dependent scale is adopted, remember
C     that only the Born kinematics is considered, since this function is called 
C     inside the btilde function before che construction of the real phase space.
      implicit none
      include 'PhysPars.h'
      include 'nlegborn.h'
      include 'pwhg_flst.h'
      include 'pwhg_kn.h'
      include 'pwhg_flg.h'
      real * 8 muf,mur
      logical ini
      data ini/.true./
      save ini
      real *8 muref
      real *8 dotp
      external dotp
      integer runningscales
      save runningscales
      real * 8 pt2
      real * 8 powheginput
      external powheginput
      if(ini) then
         runningscales=powheginput('#runningscale')
         if(runningscales.eq.1) then
            write(*,*) ""
            write(*,*) '*****************************************'
            write(*,*) '    runningscale = 1:                    '
            write(*,*) '    Factorization and renormalization    '
            write(*,*) '    scales set to the H virtuality       '
            write(*,*) '*****************************************'
         elseif(runningscales.eq.2) then
            write(*,*) ""
            write(*,*) '*****************************************'
            write(*,*) '    runningscale = 2:                    '
            write(*,*) '    Factorization and renormalization    '
            write(*,*) '    scales set to H on-shell mass in     '
            write(*,*) '    Born-like kinematic contributions    '
            write(*,*) '                                         '
            write(*,*) '    Factorization and renormalization    '
            write(*,*) '    scales set to the sqrt(pT(H)^2+mH^2) '
            write(*,*) '    real emission contributions          '
            write(*,*) '*****************************************'
         elseif(runningscales.gt.2) then
            write(*,*) ""
            write(*,*) "*****************************************"
            write(*,*) " subroutine set_fac_ren_scales(muf,mur)"
            write(*,*) " runningscale value not allowed"
            write(*,*) " runningscale value in input = ",runningscales
            write(*,*) " runningscale must be less than 2."
            write(*,*) "*****************************************"
            call exit(1)
         else
            write(*,*) ""
            write(*,*) '*****************************************'
            write(*,*) '    runningscale <= 0:                   '
            write(*,*) '    Factorization and renormalization    '
            write(*,*) '    scales set to Higgs on-shell mass    '
            write(*,*) '*****************************************'
         endif
         ini=.false.
      endif
      if(runningscales.eq.1) then
         muref=sqrt(dotp(kn_pborn(0,3),kn_pborn(0,3)))
      elseif(runningscales.eq.2) then
         muref=ph_Hmass
         if(flg_btildepart.eq.'r') then
            pt2=kn_preal(1,4)**2+kn_preal(2,4)**2
            muref=sqrt(pt2+ph_Hmass**2)
         endif
      else
         muref=ph_Hmass
      endif
      muf=muref
      mur=muref
      end

After this modification use:

runningscale 2
btlscalereal 1

in the Powheg config file.

Edit | Attach | Watch | Print version | History: r3 < r2 < r1 | Backlinks | Raw View | WYSIWYG | More topic actions
Topic revision: r3 - 2014-11-04 - ReiTanaka
 
    • Cern Search Icon Cern Search
    • TWiki Search Icon TWiki Search
    • Google Search Icon Google Search

    LHCPhysics All webs login

This site is powered by the TWiki collaboration platform Powered by PerlCopyright & 2008-2019 by the contributing authors. All material on this collaboration platform is the property of the contributing authors.
Ideas, requests, problems regarding TWiki? Send feedback